MyBrandedHOST -- Hosting Account Order Code Explained

Hosting Account Order Code Explained

Three files are included with the sample code:

process-hosting.cgi -- performs the account addition
ServerConfig.pm -- Contains your login information
XMLAPIRequest.pm -- Functions for interacting with the XML API

The first file we are going to discuss is XMLAPIRequest.pm. This file simply contains code used to create functions for accessing the XML API. YOu won't need to change this code:

									package XMLAPIRequest;


									use strict;
									use warnings;
									use Net::SSLeay qw/ make_headers get_https /;
									use MIME::Base64;


									sub new {
									   my $class = shift;
									   my %params = @_;

									   bless{
											'HOSTNAME'		=> $params{'HOSTNAME'},
											'ACCOUNT_USER'  => $params{'ACCOUNT_USER'},
											'ACCOUNT_PASS'  => $params{'ACCOUNT_PASS'},
											'PORT' 			=> '2087'
											}, $class;
									}

									sub dispatch {
										my $self = shift;
										my $page = shift;
										my @url_vars = shift;
										my %result;

										my $authinfo = $self->{'ACCOUNT_USER'} . ':' . $self->{'ACCOUNT_PASS'};

										my $header = make_headers( 
												Authorization =>  'Basic ' . 
												MIME::Base64::encode($authinfo)
												);	
										@result{'PAGE', 'RESULT', 'HEADERS'} = get_https( $self->{'HOSTNAME'} , $self->{'PORT'}, $page, $header);
										return %result;
									}

									1;

All you need to get from the above is that the methods for interacting with the XML API are new and dispatch where new creates a new XML API object and dispatch sends an XML API request. You might note that we are using Net::SSLeay so your data is traveling encrypted.

Next, we'll look at ServerConfig.pm, here you simply need to put in the username and password of root or the reseller that will be making the XML API requests. You'll also need to note the location of XMLAPIRequest.pm:

									package ServerConfig;

									use strict;
									use warnings;
									require '/home/brand.me/XMLAPIRequest.pm';


									my $hostname 		= '';     	#cPanel/WHM server to perform API action on
									my $account_user 	= '';			#User with WHM access to perform the action as
									my $account_pass	= '';	#That user's password


									our $xmlapi_object = XMLAPIRequest->new(
																'HOSTNAME' 		=> $hostname, 
																'ACCOUNT_USER' 	=> $account_user, 
																'ACCOUNT_PASS'	=> $account_pass
														);

									1;

We separated out this code so that you can put it in /home/username and not within a web readable directory. You don't want t your WHM password available to the web. This file also creates a new XMLAPI Request called $xmlapi_object for you to work with.

The real meat of the code is within process-hosting.cgi. This is where the hosting order is processed, credit cards are checked, etc. Noting that a lot of the functions in this file are simply dummy functions that you'll have to fill in (i.e. interfacing with your credit card processor, billing system, etc). First, you'll note that we have to pull in the configuration info:

											require '/home/username/ServerConfig.pm';

Then, we're gathering the info passed from our HTML order page:

												my $query = CGI->new();
												my $hostingplan = $query->param('plan');
												my $domainname = $query->param('domain');
												my $username = $query->param('user');
												my $userpass = $query->param('pass');
												my $ccnumber = $query->param('ccnum');
												my $ccexpiration = $query->param('ccexp');
												my $emailaddy = $query->param('email');

There's some logic to worry about credit cards and other things but what we're really worried about are 4 functions, the first being checkUserExists:

												sub checkUserExists{
													my $username = shift;
													my $requestline = '/xml-api/listaccts?searchtype=user&search=' . $username;
													my %userrequest = $ServerConfig::xmlapi_object->dispatch($requestline);
													my $xml = XML::Simple->new();
													my $xmlresponse = $xml->XMLin($userrequest{PAGE});
													if ( $userrequest{RESULT} =~ /HTTP\/1.0 200 OK/){
														if ($xmlresponse->{acct}){
															return 0;
														}
														else{
															return 1;
														}
													}
													else{
														print STDERR "XML API Request failure when looking up user name with checkUserExists. User: $username Error: $userrequest{RESULT}";
														return 0;
													}
												}

You'll notice that what we're doing is simply looking up whether or not the user exists on the server with the listaccts XML API call:

										my $requestline = '/xml-api/listaccts?searchtype=user&search=' . $username;
										my %userrequest = $ServerConfig::xmlapi_object->dispatch($requestline);

We then want to make sure the Net::SSLeay request succeeded:

													if ( $userrequest{RESULT} =~ /HTTP\/1.0 200 OK/){

If the request succeeded, we look for a XML object called acct. If one exists, we know one or more accounts matched our search so we should send that the function failed since the user exists (we use failure as it is an easy way to halt the process with an if statement):

												if ($xmlresponse->{acct}){
													return 0;
												}

Next is the createAccount function:

									sub createAccount{
										my ($username, $hostingplan, $password, $emailaddy) = @_;

										my $reqline = '/xml-api/createacct?username=' . $username . '&plan=' . $hostingplan . '&password=' . $userpass . '&contactemail=' . $emailaddy . '&domain=' . $domainname;
										if (isReseller($hostingplan)){	#give reseller privileges to any resellers
											$reqline .= '&reseller=1';
										}
										my %request = $ServerConfig::xmlapi_object->dispatch($reqline);	#Fire off request to XML API

										if ( $request{RESULT} =~ /HTTP\/1.0 200 OK/){	#If we get a valid response back
											my $xml2 = XML::Simple->new();
											my $acctdetails = $xml2->XMLin($request{PAGE});
											if ( $acctdetails->{result}{statusmsg} eq 'Account Creation Ok' ){
												if (isReseller($hostingplan)){	#set the reseller acl list for any resellers
													setResellerACL($username);
												}
												sendEmail($emailaddy);
												return 1;

											}
											else{	#If the account wasn't created, we have a problem
												print STDERR "Order #xxx ACCOUNT CREATION FAILED. ERROR: $request{RESULT}";
												return 0;
											}

										}  
										else{
											print STDERR "XML API Request failure when trying to create account for order xxx. Error: $request{RESULT}";
											return 0;
										}
									}

You'll notice that this is just a call to /xml-api/createacct with some error checking:

									my $reqline = '/xml-api/createacct?username=' . $username . '&plan=' . $hostingplan . '&password=' . $userpass . '&contactemail=' . $emailaddy . '&domain=' . $domainname;

We check to see which plan the user chose when they signed up. If they chose the reseller plan we add some logic to make them a reseller and setting their hosting plan correctly. First we'll add the reseller=1 variable to the xml-api request if they are a reseller:

									if (isReseller($hostingplan)){	#give reseller privileges to any resellers
										$reqline .= '&reseller=1';
									}

Later we'll set the reseller's ACL. We'll get to the setResellerACL function later:

									if (isReseller($hostingplan)){	#set the reseller acl list for any resellers
										setResellerACL($username);
									}

After we send the XML API request, we simply check to make sure the Net::SSLeay request succeeded

									my %request = $ServerConfig::xmlapi_object->dispatch($reqline);	#Fire off request to XML API

									if ( $request{RESULT} =~ /HTTP\/1.0 200 OK/){

If it did, we get the result by creating a XML::Simple object and placing the Net::SSLeay request result in it:

									my $xml2 = XML::Simple->new();
									my $acctdetails = $xml2->XMLin($request{PAGE});

Then we check the XML API statusmsg to make sure the account creation was sucessful:

									if ( $acctdetails->{result}{statusmsg} eq 'Account Creation Ok' ){

If it was successful, we can send an email with the account details:

									sendEmail($emailaddy);

You remember that we need to know whether or not the user is going to be a reseller so we'll use isReseller to check and see if their package matches a package that is a reseller package, and return 1 (true) if it does:

									sub isReseller{
										my $plan = shift;
										$plan eq 'reseller_gold' ? return 1 : return 0;
									}

If they are a reseller, we need to set their reseller privileges. We'll do this with a reseller ACL we created in the Reseller Center in WHM. Where our acl list is called reseller1:

									sub setResellerACL{
										my $username = shift;
										my $aclreqline = '/xml-api/setacls?reseller=' . $username . '&acllist=reseller1';
										my %aclrequest = $ServerConfig::xmlapi_object->dispatch($aclreqline);	#We don't validate here as if the request fails, we can set the list later. That's easier to do than halting the order process
									}

To put everything together, we need the HTML from the form used to gather the data:

									<form name="hostingorderform" id="hostingorderform" action="process-hosting.cgi" onSubmit="return checkForm();" />
										<table>
										<tr>
											<td>
												<p>Step 1: Choose your hosting plan</p>
												<div class="form" style="margin-left:15px;"><select name="plan">
																	<option value="reseller_gold">Reseller GOLD ($49.99/mo)</option>
																	<option value="hosting_silver">Hosting SILVER ($7.99/mo)</option>
																 </select>
												</div>
												<p>Step 2: Enter your domain name</p>
												<div class="form" style="margin-left:15px;"><input type="text" name="domain" /></div>
												<p>Step 3: Choose a username</p>
												<div class="form" style="margin-left:15px;"><input type="text" name="user" /></div>
												<p>Step 4: Choose a password</p>
												<div class="form" style="margin-left:15px;"><input type="password" name="pass" /></div>
												<br />
												<input type="image" src="images/submit.gif">
											</td>
											<td>
												<strong class="h_text">Billing Information</strong><br>
												<p>Step 5: Credit Card Number</p>
												<div class="form" style="margin-left:15px;"><input type="password" name="ccnum" /></div>
												<p>Step 6: Expiration Date</p>
												<div class="form" style="margin-left:15px;"><input type="password" name="ccexp" size="4" /></div>
												<p>Step 7: Email Address</p>
												<div class="form" style="margin-left:15px;"><input type="text" name="email" /></div>
											</td>
										</tr>
										</table>
										</form>

We also need some JavaScript to validate the form. Noting that you need to improve upon this JavaScript in order to validate the specific data you need. This JavaScript only ensures that the form field are not blank when the for is submitted:

									<script type="text/javascript">
									function checkForm(){
										document.getElementById("errorspace").innerHTML = '';
										var passthis = true;
										if (document.hostingorderform.domain.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter your domain name<br />';
											passthis = false;
										}
										if (document.hostingorderform.user.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter a username<br />';
											passthis = false;
										}
										if (document.hostingorderform.pass.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter a password<br />';
											passthis = false;
										}
										if (document.hostingorderform.ccnum.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter your credit card number<br />';
											passthis = false;
										}
										if (document.hostingorderform.ccexp.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter your credit card expiration date<br />';
											passthis = false;
										}
										if (document.hostingorderform.email.value == ''){
											document.getElementById("errorspace").innerHTML += 'Please enter your email address<br />';
											passthis = false;
										}
										return passthis;
									}


									</script>